Outlook の VBA で既定以外のフォルダーを取得する

Dim l_calendar As Outlook.Folder
Set l_calendar = Application.Session.GetDefaultFolder(Outlook.OlDefaultFolders.olFolderCalendar)

' 指定したパスの Outlook フォルダーを取得します。
' <params>
'   p_folderPath
'       フォルダーのパス。
' <returns>
'   p_folderPath が示す Outlook フォルダー。存在しない場合は Nothing。
Private Function GetOutlookFolder(ByVal p_folderPath As String) As Outlook.Folder
    If Left(p_folderPath, 2) = "\\" Then
        p_folderPath = Right(p_folderPath, Len(p_folderPath) - 2)
    End If
    
    ' フォルダーのパスを、フォルダー名ごとに分けて配列にします。
    Dim l_folderNames As Variant
    l_folderNames = Split(p_folderPath, "\")
    
    Dim l_folder As Outlook.Folder
    
    Dim l_folders As Outlook.Folders
    Set l_folders = Application.Session.Folders
    
    ' フォルダーを検索し、見つかればそのフォルダーを基点としてさらに子フォルダーを検索します。
    ' これをフォルダーの階層分繰り返して、目的のフォルダーを探します。
    For Each l_folderName In l_folderNames
        Set l_folder = l_folders.Item(l_folderName)
        
        If l_folder Is Nothing Then Exit Function
        
        Set l_folders = l_folder.Folders
    Next
    
    Set GetOutlookFolder = l_folder
End Function

Dim l_calendar As Outlook.Folder
Set l_calendar = GetOutlookFolder("\\テスト用 Outlook データ ファイル\テスト用予定表\テスト用予定表2")